~tyil/raku-irc-client-plugin-reminders

raku-irc-client-plugin-reminders/lib/IRC/Client/Plugin/Reminders.rakumod -rw-r--r-- 3.7 KiB View raw
e78ba1ae — Patrick Spek Add reminder functionality a month ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
#! /usr/bin/env false

use v6.d;

use Config;
use IRC::Client;

use IRC::Client::Plugin::Reminders::Grammar;
use IRC::Client::Plugin::Reminders::Actions;

constant ReminderGrammar = IRC::Client::Plugin::Reminders::Grammar;
constant ReminderActions = IRC::Client::Plugin::Reminders::Actions;

unit class IRC::Client::Plugin::Reminders is IRC::Client::Plugin;

#| The configuration object for the bot.
has Config $.config;

#| A hash of prepared statements held by this plugin.
has %!stmt;

#| A connection to the database held by this plugin.
has $!db;

#| The interval in minutes in which the bot is supposed to run.
has $!interval;

method reload-config (
	Config $config,
) {
	$!config = $config;

	self.TWEAK;
}

multi method irc-to-me (
	$event where *.text.starts-with('remind me'),
) {
	# TODO: Allow people to set reminders for others?

	my $result = ReminderGrammar.parse(
		$event.text,
		:actions(ReminderActions),
	);

	return "I didn't quite catch that" unless $result;

	my %reminder = $result.made;

	%!stmt<create>.execute(
		%reminder<subject>,
		$event.usermask,
		$event.?channel // Any,
		%reminder<delay>.at,
	);

	"Reminding you to {%reminder<subject>} on {%reminder<delay>.at} (UTC)"
}

method irc-connected (
	$event,
) {
	.debug("Interval set to $!interval minute(s)") with $*LOG;

	# TODO: Check tables for reminders that were missed while the bot was
	# offline.

	# Check for reminders in a seperate thread, so we don't hang the bot.
	# TODO: Dynamic variable isn't set inside the start{}?
	start {
		react {
			whenever Supply.interval($!interval × 60) {
				CATCH {
					default {
						.crit('Error in reminder thread!') with $*LOG;
					}
				}

				.notice('Checking for reminders at ' ~ DateTime.now.utc) with $*LOG;

				my @results = %!stmt<read>.execute.hashes;

				for @results -> %result {
					# Send the reminder.
					my $text = "Reminder to {%result<subject>}";

					if (%result<created_in>) {
						$text = %result<created_by>.split('!', 2).first ~ ': ' ~ $text;
					}

					$event.irc.send(
						:$text,
						:where(%result<created_in> // %result<created_by>),
					);

					# And clean up the reminder from the
					# database.
					%!stmt<delete>.execute(%result<id>);
				}
			}
		}
	}
}

submethod TWEAK
{
	$!interval = $!config.get('irc.plugins.reminders.interval', 1).?Int;

	if (!$!db) {
		if (!$*DB) {
			.emergency('No database connection in $*DB') with $*LOG;
			return;
		}
		.debug('Preparing database') with $*LOG;

		$!db = $*DB.db;

		%!stmt<create> = $!db.prepare(q:to/SQL/);
			INSERT INTO reminders (
				subject,
				created_by,
				created_in,
				trigger_at
			) VALUES ($1, $2, $3, $4)
			SQL

		%!stmt<read> = $!db.prepare(q:to/SQL/);
			SELECT *
			FROM reminders
			WHERE trigger_at <= (NOW() AT TIME ZONE 'utc')
			ORDER BY trigger_at ASC
			SQL
		%!stmt<delete> = $!db.prepare(q:to/SQL/);
			DELETE FROM reminders
			WHERE id = $1
			SQL
	}
}

=begin pod

=NAME    IRC::Client::Plugin::Reminders
=VERSION 0.0.0
=AUTHOR  Patrick Spek <p.spek@tyil.nl>

=begin LICENSE
Copyright © 2020

This program is free software: you can redistribute it and/or modify it under
the terms of the GNU Affero General Public License as published by the Free
Software Foundation, either version 3 of the License, or (at your option) any
later version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
PARTICULAR PURPOSE.  See the GNU Affero General Public License for more
details.

You should have received a copy of the GNU Affero General Public License along
with this program.  If not, see http://www.gnu.org/licenses/.
=end LICENSE

=end pod

# vim: ft=raku noet sw=8 ts=8