~subsetpark/ec

ref: c27b383a7158690b1fc7afbca9916942dca67db7 ec/src/calc.janet -rw-r--r-- 4.0 KiB
c27b383a — Zach Smith set out-arity for quotations (i think this is valid. whenever you push a quotation to the stack, it always takes one unit) 11 months ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
(use fugue)

(defproto Stack () data {:default @[]})

(defproto Element ()
  doc {:default ""})

(defproto Number Element
  out-arity {:allocate-value 1})

(defproto Int Number
  type {:allocate-value :integer}
  value {:init? true})

(defproto Float Number
  type {:allocate-value :float}
  value {:init? true})

(defproto Operation Element
  type {}
  arity {}
  out-arity {}
  fun-ref {})

(defproto Adverb Element
  type {}
  arity {}
  out-arity {})

(defproto Quotation Element
  shape {:default [] :init? true}
  out-arity {:allocate-value 1}
  data {:init? true}
  type {:allocate-value :quotation})

(defgeneric get-shape [_] [])
(defmethod get-shape Quotation [self] (self :shape))

(defgeneric get-arity [_] 0)
(defmethod get-arity Adverb [a] (a :arity))
(defmethod get-arity Operation [a] (a :arity))
(defmethod get-arity Quotation [q]
  (def arities @[])
  (loop [i :range [0 (length (q :data))]]
    (if (zero? i)
      (array/push arities (get-arity ((q :data) i)))
      (array/push arities
                  (+ (last arities)
                     (- (get-arity ((q :data) i))
                        (((q :data) (dec i)) :out-arity))))))
  (max ;arities))

(defgeneric fill
  [element shape-to-fill]
  (if (empty? shape-to-fill)
    element
    (let [y (array ;shape-to-fill)
          yi (last y)
          v (:new Quotation [yi] (array/new-filled yi element))]
      (fill v y))))

(defmethod fill Quotation
  [self shape-to-fill]
  (let [x (array ;(shape self))
        y (array ;shape-to-fill)]

    (while (not (empty? x))
      (let [xi (array/pop x)
            yi (array/pop y)]
        (unless (= xi yi)
          (errorf "Shape error: can't fill quotation with shape %q to %q"
                  (shape self) shape-to-fill))))

    (reduce (fn [acc length]
              (let [new-shape (tuple length ;(shape acc))
                    new-data (array/new-filled length acc)]
                (:new Quotation new-shape new-data)))
            self
            (reverse y))))

# TODO: Do we want to do something more sophisticated here?
(defmulti make-element [:number] [n] (:new Float n
                                           :doc (string n)))
(defmulti make-element [_] [v] v)

(defn- inner-apply
  [op & args]
  (let [x (first args)]
    (if (Quotation? x)
      (:new Quotation
            (x :shape)
            (map (partial inner-apply op) ;(map |($ :data) args)))
      (let [f (op :fun-ref)
            unwrapped (map |($ :value) args)]
        (->> (f ;unwrapped)
             (make-element))))))

(defmethod apply-operation Operation
  [op & args]
  (let [cmpr (comp length get-shape)
        largest (get-shape (extreme |(> (cmpr $0) (cmpr $1)) args))
        filled (map |(fill $ largest) args)]
    (inner-apply op ;filled)))

(defn wrap
  [& data]
  (let [hd (first data)
        inner-shape (get-shape hd)]
    (each datum data
      (unless (deep= (get-shape datum) inner-shape)
        (errorf "Quotation error: can't wrap heterogeneous data. Expected %j, got %j."
                inner-shape
                (get-shape datum))))
    (:new Quotation (tuple (length data) ;inner-shape) data)))

(defmethod pop Stack
  [self]
  (-> (self :data) (array/pop)))

(defmethod peek Stack
  [self]
  (-> (self :data) (last)))

(defmethod size Stack
  [self]
  (-> (self :data) (length)))

(defn check-arity
  [stack elem]
  (let [arity (get-arity elem)]
    (when (> arity (size stack))
      (errorf "Not enough stack: %s has arity %i; stack has size %i"
              (string (elem :type))
              arity
              (size stack)))))

(defmulti push [Stack Operation]
  [self op]
  (check-arity self op)

  (def buf @[])
  (loop [_ :range [0 (get-arity op)]]
    (array/insert buf 0 (pop self)))

  (->> (apply-operation op ;buf)
       (make-element)
       (push self)))

(defmulti push [Stack Adverb]
  [self adv]
  (check-arity self adv)
  ((adv :fun-ref) self))

(defmulti push [Stack _]
  [self item]
  (array/push (self :data) item))

(defn shape?
  [obj]
  (and (Quotation? obj) (all Number*? (obj :data))))