~sircmpwn/sr.ht-pkgbuilds

ref: f6f509861162091ec4764c075bf9bd24924d3ded sr.ht-pkgbuilds/paste.sr.ht/PKGBUILD -rw-r--r-- 1.5 KiB
f6f50986Eli Schwartz pkgrel bump all remaining packages that still need to be rebuilt for py3.10 10 months ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
pkgname=paste.sr.ht
pkgver=0.13.6
pkgrel=3
pkgdesc="sr.ht pastebin services"
arch=("x86_64")
license=("AGPL3")
url="https://git.sr.ht/~sircmpwn/paste.sr.ht"
install=paste.sr.ht.install
depends=(
	"python-srht"
	"python-yaml"
	"gunicorn"
)
makedepends=("python-setuptools" "nodejs" "sassc" "go")
source=(
	"$pkgname-$pkgver.tar.gz::http://git.sr.ht/~sircmpwn/$pkgname/archive/$pkgver.tar.gz"
	"paste.sr.ht.service"
	"paste.sr.ht-webhooks.service"
	"paste.sr.ht-api.service"
	"sysusers.conf"
)
sha256sums=('a01f4abebbcb45b334add6e9e190c06881aabd9d3751238bb2a60195025bddbd'
            '6f99b3bedea1cad4f28658950ecf802c05e38433432f2d1e73ee88864a36d8ec'
            'a4638073cc6486f4a693aa7cb18c21fa66e70ad0387eb423166d644cdfb32d26'
            '5901e68427fc15a94122dad22f2db363ea571562d757ce48e901458fe6d2a505'
            'a08895ba853dbca7fc5af3da2f6bfd4284c15f787a5968793a4a53f31f9de817')
export PKGVER=$pkgver

build() {
	cd $pkgbase-$pkgver
	python3 setup.py build
	cd api
	go build -o pastesrht-api
}

package() {
	cd $pkgbase-$pkgver
	install -Dm0644 ../paste.sr.ht.service -t "$pkgdir"/usr/lib/systemd/system/
	install -Dm0644 ../paste.sr.ht-webhooks.service \
		-t "$pkgdir"/usr/lib/systemd/system/
	install -Dm644 ../paste.sr.ht-api.service -t "$pkgdir"/usr/lib/systemd/system/
	install -Dm0644 ../sysusers.conf "$pkgdir/usr/lib/sysusers.d/paste.sr.ht.conf"
	install -Dm755 api/pastesrht-api "$pkgdir"/usr/bin/pastesrht-api
	python3 setup.py install --root="${pkgdir}" --optimize=1
}