~sircmpwn/casa

ref: 0587e73106a05f1c0b7bd1cac31baa8ab287fc98 casa/meson.build -rw-r--r-- 1.2 KiB View raw
0587e731Drew DeVault Add libdrm dependency to meson.build 3 months ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
project(
	'casa',
	'c',
	version: '0.1.0',
	license: 'MIT',
	meson_version: '>=0.49.0',
	default_options: [
		'c_std=c11',
		'warning_level=2',
		'werror=true',
	],
)

cc = meson.get_compiler('c')

add_project_arguments(cc.get_supported_arguments([
	'-Wundef',
	'-Wlogical-op',
	'-Wmissing-include-dirs',
	'-Wold-style-definition',
	'-Wpointer-arith',
	'-Winit-self',
	'-Wstrict-prototypes',
	'-Wimplicit-fallthrough=2',
	'-Wendif-labels',
	'-Wstrict-aliasing=2',
	'-Woverflow',

	'-Wno-missing-braces',
	'-Wno-missing-field-initializers',
	'-Wno-unused-parameter',
]), language: 'c')

cairo = dependency('cairo')
drm = dependency('libdrm')
egl = dependency('egl')
gles2 = dependency('glesv2')
fdicons = dependency('fdicons')
gbm = dependency('gbm')
wayland_client = dependency('wayland-client')
wayland_protocols = dependency('wayland-protocols')

subdir('protocols')

casa = executable('casa',
	files(
		'src/buffers.c',
		'src/input.c',
		'src/main.c',
		'src/output.c',
		'src/prerender.c',
		'src/render.c',
		'src/shaders.c',
		'src/surface.c',
	),
	dependencies: [
		cairo,
		client_protos,
		drm,
		egl,
		gbm,
		gles2,
		fdicons,
		wayland_client,
	],
	include_directories: include_directories('include'),
)