(ns io.dominic.wedge.mise.rebel
  (:require
    [clojure.tools.deps.alpha.repl :as tda.repl]
    [io.dominic.wedge.mise :as mise]
    [io.dominic.wedge.mise.impl.nrepl :as nrepl]))

(defn- add-libs
  []
  (binding [;; Suppress missing S3Transport warning
            *err* (java.io.StringWriter.)]
    (tda.repl/add-libs
      (cond->
        '{com.bhauman/rebel-readline {:mvn/version "0.1.4"}
          mvxcvi/puget {:mvn/version "1.3.1"}}
        (try (require 'cljs.analyzer)
             true
             (catch java.io.FileNotFoundException _
               false))
        (assoc 'com.bhauman/rebel-readline-cljs {:mvn/version "0.1.4"}))))
  :loaded)

(defn -main
  [& args]
  (let [cl (.getContextClassLoader (Thread/currentThread))]
    (.setContextClassLoader (Thread/currentThread) (clojure.lang.DynamicClassLoader. cl)))
  (mise/load-libs)
  (mise/setup)
  (when (some #{"--nrepl"} args)
    (nrepl/add-libs)
    (nrepl/start-nrepl))
  (add-libs)
  (load "io/dominic/wedge/mise/rebel/impl")
  ((resolve 'main*)))