~rkta/blog

blog/stddef.m4 -rw-r--r-- 1.2 KiB
8a0c1677Rene Kita Add note about Advanced line types 6 days ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
divert(-1)dnl Suppress empty lines

dnl ============================================================================
dnl Macros for internal usage only
dnl ============================================================================

define(`ALINK', <li>$1 <a href=./$2.html>$3</a></li>)
define(`SITETITLE', Rene Kita&apos;s weblog)
define(`FENTRY', `
	<entry>
		<title>$3</title>
		<link href="https://rkta.de/$1.html"/>
		<updated>$2</updated>
		<id>https://rkta.de/$1.html</id>
		<summary>$3</summary>
		<content type="html" xml:lang="en">
			<![CDATA[
			include($1.html)
			]]>
		</content>
	</entry>')

dnl ============================================================================
dnl Macros for the user
dnl ============================================================================

dnl # A code block
define(`CODE', <code>$1</code>)

dnl # HTML footnotes
dnl   Use FN(word) or word`'FN to add link to a footnote to word
dnl   Use FNL(`footnote') inside a <ul> to add an list entry with the footnote
define(`__fnc', 0)
define(`FN', `$1<a href=`#'__fnc>`#'__fnc</a>define(`__fnc', incr(__fnc))')
define(`__fnlc', 0)
define(`FNL', `<li id=__fnlc>__fnlc: $1</li>define(`__fnlc', incr(__fnlc))')
divert(0)dnl