~q3cpma/portage-overlay

ref: 2a3d524c561c0cbccb8fbd94a7cb4e7a4e3af8a8 portage-overlay/media-fonts/source-han-serif/source-han-serif-2.001.ebuild -rw-r--r-- 1.5 KiB
2a3d524cq3cpma Bump source-han-{sans,serif} and add source-han-mono 3 months ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit font

# Note to maintainers:
# The upstream tarball is huge (over 700 MB), so we use the
# regional subset OTF fonts per region, for the user's convenience.

DESCRIPTION="Pan-CJK OpenType/CFF serif font family"
HOMEPAGE="https://github.com/adobe-fonts/source-han-serif/"
SRC_URI="
	l10n_ja? (    https://github.com/adobe-fonts/${PN}/releases/download/${PV}R/12_SourceHanSerifJP.zip -> ${PN}-ja-${PV}.zip )
	l10n_ko? (    https://github.com/adobe-fonts/${PN}/releases/download/${PV}R/13_SourceHanSerifKR.zip -> ${PN}-ko-${PV}.zip )
	l10n_zh-CN? ( https://github.com/adobe-fonts/${PN}/releases/download/${PV}R/14_SourceHanSerifCN.zip -> ${PN}-zh_CN-${PV}.zip )
	l10n_zh-HK? ( https://github.com/adobe-fonts/${PN}/releases/download/${PV}R/16_SourceHanSerifHK.zip -> ${PN}-zh_HK-${PV}.zip )
	l10n_zh-TW? ( https://github.com/adobe-fonts/${PN}/releases/download/${PV}R/15_SourceHanSerifTW.zip -> ${PN}-zh_TW-${PV}.zip )"
S="${WORKDIR}"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 ~ia64 ppc ppc64 ~riscv sparc x86 ~x64-macos"
IUSE="l10n_ja l10n_ko +l10n_zh-CN l10n_zh-HK l10n_zh-TW"
REQUIRED_USE="|| ( l10n_ja l10n_ko l10n_zh-CN l10n_zh-HK l10n_zh-TW )"
RESTRICT="binchecks strip"

FONT_SUFFIX="otf"

BDEPEND="app-arch/unzip"

src_install() {
	declare -A map=(ja JP ko KR zh-CN CN zh-HK HK zh-TW TW)
	for u in ${IUSE//+/}; do
		! [[ $u =~ ^l10n_ ]] && continue
		use $u && FONT_S="$S/SubsetOTF/${map[${u#l10n_}]}/" font_src_install
	done
}