~lattis/muon

ref: f9a8cbad39b665a9496cd3adb4756e85ee5ec97c muon/src/meson.build -rw-r--r-- 2.0 KiB
f9a8cbadStone Tickle print stdout/stderr of failing test 4 months ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
src = files([
	'args.c',
	'coerce.c',
	'compilers.c',
	'data/bucket_array.c',
	'data/darr.c',
	'data/hash.c',
	'error.c',
	'formats/ini.c',
	'formats/tar.c',
	'functions/array.c',
	'functions/boolean.c',
	'functions/build_target.c',
	'functions/common.c',
	'functions/compiler.c',
	'functions/configuration_data.c',
	'functions/custom_target.c',
	'functions/default.c',
	'functions/default/configure_file.c',
	'functions/default/custom_target.c',
	'functions/default/dependency.c',
	'functions/default/options.c',
	'functions/default/setup.c',
	'functions/dependency.c',
	'functions/dict.c',
	'functions/external_library.c',
	'functions/external_program.c',
	'functions/feature_opt.c',
	'functions/file.c',
	'functions/machine.c',
	'functions/meson.c',
	'functions/modules.c',
	'functions/modules/fs.c',
	'functions/modules/pkgconfig.c',
	'functions/modules/python.c',
	'functions/number.c',
	'functions/run_result.c',
	'functions/string.c',
	'functions/subproject.c',
	'install.c',
	'lang/eval.c',
	'lang/interpreter.c',
	'lang/lexer.c',
	'lang/object.c',
	'lang/parser.c',
	'lang/serial.c',
	'lang/workspace.c',
	'log.c',
	'machine_file.c',
	'main.c',
	'opts.c',
	'output/output.c',
	'platform/dirs.c',
	'platform/filesystem.c',
	'platform/mem.c',
	'platform/path.c',
	'platform/run_cmd.c',
	'sha_256.c',
	'tests.c',
	'wrap.c',
]) + [configure_file(
	configuration: version_info,
	input: 'version.c.in',
	output: 'version.c'
)]

foreach d: [
		['libcurl',    'curl',       'dependency'],
		['zlib',       'zlib',       'dependency'],
		['libpkgconf', 'libpkgconf', 'dependency'],
		['samurai',    'samu',       'subproject', 'libsamu_dep'],
	]

	found = false

	if d[2] == 'subproject'
		if not get_option(d[1]).disabled()
			sub = subproject(d[0])
			dep = sub.get_variable(d[3])
			found = true
		endif
	else
		dep = dependency(d[0], required: get_option(d[1]), static: get_option('static'))
		found = dep.found()
	endif

	if found
		deps += [dep]
		src += [files(['external/' + d[1] + '.c'])]
	else
		src += [files(['external/' + d[1] + '_null.c'])]
	endif
endforeach