~kaction/config

ref: 04f9f3772959d641aab7e658b237a68d9d74e0ed config/universe/python3/overrides.nix -rw-r--r-- 2.4 KiB
04f9f377 — Dmitry Bogatov Fix unneeded dependency on X11 1 year, 1 month ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
self: super: {
  # There is no need in libusb1 backend, since I use trezord-go backend
  # which works more reliably for me: libusb1 complains that it can't
  # load musl libc. Not sure why it tries to do so.
  trezor = super.trezor.overrideAttrs (old: {
    propagatedBuildInputs =
      builtins.filter (p: p != super.libusb1 && p != super.hidapi)
      old.propagatedBuildInputs;
    postPatch = ''
      sed -i '/libusb1/ d' setup.py
      sed -i '/libusb1/ d' requirements.txt
    '';
  });
  trezor_agent = super.trezor_agent.overrideAttrs (old: {
    propagatedBuildInputs =
      builtins.filter (p: p != super.keepkey) old.propagatedBuildInputs;
    postPatch = ''
      sed -i 's,\[hidapi\],,g' setup.py
    '';
  });

  python_docs_theme = super.buildPythonPackage rec {
    pname = "python_docs_theme";
    version = "2020-09-15-unstable";
    src = builtins.fetchGit {
      url = "https://github.com/python/python-docs-theme";
      rev = "a0d0d8b2649ac9556f1d16b16aae17e05580813b";
    };
  };
  sphinx_bootstrap_theme = super.buildPythonPackage rec {
    pname = "sphinx-bootstrap-theme";
    version = "0.7.1";
    src = super.fetchPypi {
      inherit pname version;
      sha256 = "024x4w38h4h0aac58nssqkd7mg3fdf14m8kaaw36qk3dnz6467jp";
    };
    doCheck = false;
    doInstallCheck = false;
  };
  cjkwrap = super.buildPythonPackage rec {
    pname = "CJKwrap";
    version = "2.2";
    src = super.fetchPypi {
      inherit pname version;
      sha256 = "1b603sg6c2gv9vmlxwr6r1qvhadqk3qp6vifmijris504zjx5ix2";
    };
  };
  mistune_2_0_0 = super.buildPythonApplication rec {
    pname = "mistune";
    version = "2.0.0a4";
    src = super.fetchPypi {
      inherit pname version;
      sha256 = "0i6cblmjl58kdmaa21xm0l1ls0kvjpfy45sf73fw3ws6305f628k";
    };
    doCheck = false;
    doInstallCheck = false;
  };
  md2gemini = super.buildPythonApplication rec {
    pname = "md2gemini";
    version = "1.7.0";
    propagatedBuildInputs = with self; [ mistune_2_0_0 cjkwrap wcwidth ];
    checkInputs = with self; [ pytest ];
    src = super.fetchPypi {
      inherit pname version;
      sha256 = "1dkjs4cfbg8hgg6bwr9sjcv91m72r83j97sgz3cfnk1p9dpmdd81";
    };
  };

  python-pure-cdb = super.buildPythonPackage {
    pname = "python-pure-cdb";
    version = "3.1.1";
    src = builtins.fetchGit {
      url = "https://github.com/bbayles/python-pure-cdb";
      rev = "a1f496a95b892c1304e637fb352f663c65eb2655";
    };
    checkInputs = with self; [ flake8 ];
  };
  tkinter = null;
}