program = { declaration }, EOF;

declaration = ( classDecl | funDecl | varDecl | statement ), ";";
classDecl   = "class", IDENTIFIER, [ "<", IDENTIFIER ], "{", { function }, "}";
funDecl     = "fun", function;
varDecl     = "var", IDENTIFIER, [ "=", expression ], ";";
statement   = block | exprStmt | ifStmt | forStmt | printStmt | returnStmt | whileStmt;

function   = IDENTIFIER, "(", [ parameters ], ")", block;
arguments  = expression, { ",", expression };
parameters = IDENTIFIER, { ",", IDENTIFIER };

block      = "{", { declaration }, "}";
exprStmt   = expression, ";";
ifStmt     = "if", "(", expression, ")", statement, [ "else", statement ];
forStmt    = "for", "(", ( varDecl | exprStmt | ";" ), [ expression ], ";", [ expression ], ")", statement;
printStmt  = "print", expression, ";";
returnStmt = "return", [ expression ], ";";
whileStmt  = "while", "(", expression,  ")", statement;

expression = assignment;
assignment = [ call, "." ], IDENTIFIER, "=", ( assignment | logicOr );
logicOr    = logicAnd, { "or", logicAnd };
logicAnd   = equality, { "and", equality };
equality   = comparison, { ( "!=" | "==" ), comparison };
comparison = term, { ( ">" | ">=" | "<" | "<=" ), term };
term       = factor, { ( "-" | "+" ), factor };
factor     = unary, { ( "/" | "*" ), unary }; (* Same as [ factor, ( "/" | "*" ) ], unary; *)
unary      = ( "!" | "-" ), unary | call;
call       = primary, { ( "(", [ arguments ], ")" ) | ".", IDENTIFIER };
primary    = IDENTIFIER | NUMBER | STRING
             | "true" | "false" | "nil" | "this"
             | ( "super", ".", IDENTIFIER ) | "(", expression, ")";