~evhan/chicken-sourcehut

09c7af8a1e031b0a48f784c49b7f99b46e6e3ce9 — Evan Hanson 1 year, 4 months ago 1101477 test
Add nix configs and niv sources
7 files changed, 262 insertions(+), 0 deletions(-)

M .gitignore
M README.md
A default.nix
A nix/sources.json
A nix/sources.nix
A shell.nix
A sourcehut.egg.lock
M .gitignore => .gitignore +1 -0
@@ 6,3 6,4 @@
*.so
*.types
.envrc
/result/

M README.md => README.md +4 -0
@@ 155,6 155,10 @@ pandoc -s -i sourcehut.1.md -o sourcehut.1
pandoc -s -i sourcehut.1.md -o sourcehut.html --toc --section-divs --css https://foldling.org/html/files/css/main.css
```

Nix users can use `nix-shell` to pull in dependencies for local development, or
run `nix-build` to produce a packaged version of the CLI application. The output
will be linked from `./result` and can be called via `./result/bin/sourcehut`.

## License

Three-clause BSD. See LICENSE for details.

A default.nix => default.nix +48 -0
@@ 0,0 1,48 @@
{ eggsHash ? "sha256:088jzdkv3zp2b23a98wcjjcycg3ai59x912byma7dil3wkvc50fb" }:
let
  pkgs = import (import ./nix/sources.nix).nixpkgs {};
  eggs = with pkgs; stdenv.mkDerivation {
    name = "chicken-sourcehut-dependencies";
    src = ./.;
    buildInputs = [ chicken ];
    outputHash = eggsHash;
    outputHashMode = "recursive";
    CHICKEN_EGG_CACHE = "eggs";
    buildPhase = ''
      chicken-install -retrieve -recursive -override sourcehut.egg.lock
    '';
    installPhase = ''
      mv $CHICKEN_EGG_CACHE $out
      find $out -name STATUS -delete -or -name TIMESTAMP -delete
    '';
  };
  sourcehut = with pkgs; stdenv.mkDerivation {
    name = "chicken-sourcehut";
    src = ./.;
    buildInputs = [ chicken makeWrapper openssl pkg-config ];
    CHICKEN_EGG_CACHE = "/tmp/eggs";
    CHICKEN_INSTALL_PREFIX = "/tmp/out";
    CHICKEN_INSTALL_REPOSITORY = "/tmp/out/lib";
    CHICKEN_REPOSITORY_PATH = "/tmp/out/lib";
    postUnpack = ''
      cp -R -L ${eggs} $CHICKEN_EGG_CACHE
      chmod -R +w $CHICKEN_EGG_CACHE
    '';
    buildPhase = ''
      chicken-install -cached -from-list sourcehut.egg.lock
      chicken-install
    '';
    installPhase = ''
      mv /tmp/out $out
      find $out/lib \
        -type f -not -name \*.so -delete -or \
        -type f -name \*.import.so -not -name openssl.import.so -delete
      wrapProgram $out/bin/sourcehut \
        --prefix CHICKEN_INCLUDE_PATH : $out/share \
        --prefix CHICKEN_REPOSITORY_PATH : $out/lib \
        --prefix LD_LIBRARY_PATH : ${chicken}/lib \
        --prefix LD_LIBRARY_PATH : ${openssl}/lib
    '';
  };
in
  sourcehut

A nix/sources.json => nix/sources.json +26 -0
@@ 0,0 1,26 @@
{
    "niv": {
        "branch": "master",
        "description": "Easy dependency management for Nix projects",
        "homepage": "https://github.com/nmattia/niv",
        "owner": "nmattia",
        "repo": "niv",
        "rev": "3cd7914b2c4cff48927e11c216dadfab7d903fe5",
        "sha256": "1agq4nvbhrylf2s77kb4xhh9k7xcwdwggq764k4jgsbs70py8cw3",
        "type": "tarball",
        "url": "https://github.com/nmattia/niv/archive/3cd7914b2c4cff48927e11c216dadfab7d903fe5.tar.gz",
        "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz"
    },
    "nixpkgs": {
        "branch": "nixos-20.09",
        "description": "Nix Packages collection",
        "homepage": null,
        "owner": "NixOS",
        "repo": "nixpkgs",
        "rev": "1eff582e7ea6dcb208127ad369e231eaaf6fa378",
        "sha256": "1p29xyspvcy7fna9gn9qj9ha0kdn2malp815cjw70bxx1dxsa0kl",
        "type": "tarball",
        "url": "https://github.com/NixOS/nixpkgs/archive/1eff582e7ea6dcb208127ad369e231eaaf6fa378.tar.gz",
        "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz"
    }
}

A nix/sources.nix => nix/sources.nix +148 -0
@@ 0,0 1,148 @@
# This file has been generated by Niv.

let

  #
  # The fetchers. fetch_<type> fetches specs of type <type>.
  #

  fetch_file = pkgs: spec:
    if spec.builtin or true then
      builtins_fetchurl { inherit (spec) url sha256; }
    else
      pkgs.fetchurl { inherit (spec) url sha256; };

  fetch_tarball = pkgs: name: spec:
    let
      ok = str: ! builtins.isNull (builtins.match "[a-zA-Z0-9+-._?=]" str);
      # sanitize the name, though nix will still fail if name starts with period
      name' = stringAsChars (x: if ! ok x then "-" else x) "${name}-src";
    in
      if spec.builtin or true then
        builtins_fetchTarball { name = name'; inherit (spec) url sha256; }
      else
        pkgs.fetchzip { name = name'; inherit (spec) url sha256; };

  fetch_git = spec:
    builtins.fetchGit { url = spec.repo; inherit (spec) rev ref; };

  fetch_local = spec: spec.path;

  fetch_builtin-tarball = name: throw
    ''[${name}] The niv type "builtin-tarball" is deprecated. You should instead use `builtin = true`.
        $ niv modify ${name} -a type=tarball -a builtin=true'';

  fetch_builtin-url = name: throw
    ''[${name}] The niv type "builtin-url" will soon be deprecated. You should instead use `builtin = true`.
        $ niv modify ${name} -a type=file -a builtin=true'';

  #
  # Various helpers
  #

  # The set of packages used when specs are fetched using non-builtins.
  mkPkgs = sources:
    let
      sourcesNixpkgs =
        import (builtins_fetchTarball { inherit (sources.nixpkgs) url sha256; }) {};
      hasNixpkgsPath = builtins.any (x: x.prefix == "nixpkgs") builtins.nixPath;
      hasThisAsNixpkgsPath = <nixpkgs> == ./.;
    in
      if builtins.hasAttr "nixpkgs" sources
      then sourcesNixpkgs
      else if hasNixpkgsPath && ! hasThisAsNixpkgsPath then
        import <nixpkgs> {}
      else
        abort
          ''
            Please specify either <nixpkgs> (through -I or NIX_PATH=nixpkgs=...) or
            add a package called "nixpkgs" to your sources.json.
          '';

  # The actual fetching function.
  fetch = pkgs: name: spec:

    if ! builtins.hasAttr "type" spec then
      abort "ERROR: niv spec ${name} does not have a 'type' attribute"
    else if spec.type == "file" then fetch_file pkgs spec
    else if spec.type == "tarball" then fetch_tarball pkgs name spec
    else if spec.type == "git" then fetch_git spec
    else if spec.type == "local" then fetch_local spec
    else if spec.type == "builtin-tarball" then fetch_builtin-tarball name
    else if spec.type == "builtin-url" then fetch_builtin-url name
    else
      abort "ERROR: niv spec ${name} has unknown type ${builtins.toJSON spec.type}";

  # If the environment variable NIV_OVERRIDE_${name} is set, then use
  # the path directly as opposed to the fetched source.
  replace = name: drv:
    let
      saneName = stringAsChars (c: if isNull (builtins.match "[a-zA-Z0-9]" c) then "_" else c) name;
      ersatz = builtins.getEnv "NIV_OVERRIDE_${saneName}";
    in
      if ersatz == "" then drv else ersatz;

  # Ports of functions for older nix versions

  # a Nix version of mapAttrs if the built-in doesn't exist
  mapAttrs = builtins.mapAttrs or (
    f: set: with builtins;
    listToAttrs (map (attr: { name = attr; value = f attr set.${attr}; }) (attrNames set))
  );

  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/lists.nix#L295
  range = first: last: if first > last then [] else builtins.genList (n: first + n) (last - first + 1);

  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/strings.nix#L257
  stringToCharacters = s: map (p: builtins.substring p 1 s) (range 0 (builtins.stringLength s - 1));

  # https://github.com/NixOS/nixpkgs/blob/0258808f5744ca980b9a1f24fe0b1e6f0fecee9c/lib/strings.nix#L269
  stringAsChars = f: s: concatStrings (map f (stringToCharacters s));
  concatStrings = builtins.concatStringsSep "";

  # fetchTarball version that is compatible between all the versions of Nix
  builtins_fetchTarball = { url, name, sha256 }@attrs:
    let
      inherit (builtins) lessThan nixVersion fetchTarball;
    in
      if lessThan nixVersion "1.12" then
        fetchTarball { inherit name url; }
      else
        fetchTarball attrs;

  # fetchurl version that is compatible between all the versions of Nix
  builtins_fetchurl = { url, sha256 }@attrs:
    let
      inherit (builtins) lessThan nixVersion fetchurl;
    in
      if lessThan nixVersion "1.12" then
        fetchurl { inherit url; }
      else
        fetchurl attrs;

  # Create the final "sources" from the config
  mkSources = config:
    mapAttrs (
      name: spec:
        if builtins.hasAttr "outPath" spec
        then abort
          "The values in sources.json should not have an 'outPath' attribute"
        else
          spec // { outPath = replace name (fetch config.pkgs name spec); }
    ) config.sources;

  # The "config" used by the fetchers
  mkConfig =
    { sourcesFile ? if builtins.pathExists ./sources.json then ./sources.json else null
    , sources ? if isNull sourcesFile then {} else builtins.fromJSON (builtins.readFile sourcesFile)
    , pkgs ? mkPkgs sources
    }: rec {
      # The sources, i.e. the attribute set of spec name to spec
      inherit sources;

      # The "pkgs" (evaluated nixpkgs) to use for e.g. non-builtin fetchers
      inherit pkgs;
    };

in
mkSources (mkConfig {}) // { __functor = _: settings: mkSources (mkConfig settings); }

A shell.nix => shell.nix +9 -0
@@ 0,0 1,9 @@
let
  repo = "${builtins.toString ./.}/chicken";
  pkgs = import (import ./nix/sources.nix).nixpkgs {};
in pkgs.mkShell {
  CHICKEN_INSTALL_PREFIX = "${repo}";
  CHICKEN_INSTALL_REPOSITORY = "${repo}/lib";
  CHICKEN_REPOSITORY_PATH = "${repo}/lib";
  propagatedBuildInputs = with pkgs; [ chicken openssl pandoc ];
}

A sourcehut.egg.lock => sourcehut.egg.lock +26 -0
@@ 0,0 1,26 @@
("lazy-seq" "2")
("srfi-18" "0.1.6")
("medea" "4")
("uri-generic" "3.2")
("srfi-69" "0.4.1")
("srfi-133" "1.6")
("openssl" "2.0.7")
("trie" "2")
("base64" "1.0")
("defstruct" "2.0")
("srfi-13" "0.3")
("begin-syntax" "0.2.1")
("comparse" "3")
("simple-exceptions" "1.3.1")
("matchable" "1.1")
("sendfile" "1.8.3")
("address-info" "1.0.5")
("optimism" "0.1.0")
("module-declarations" "0.2.1")
("srfi-1" "0.5.1")
("memory-mapped-files" "0.4")
("intarweb" "2.0.1")
("http-client" "1.2")
("srfi-14" "0.2.1")
("simple-md5" "0.1.1")
("uri-common" "2.0")